--This program plays a BAM file, and displays status messages to the
--stdout as it goes.

------------------------------------------------------------------------

include fmsynth.e
include bobsfile.e

------------------------------------------------------------------------

constant false=0
constant true=1
constant stdout=1

------------------------------------------------------------------------

sequence bam_file_to_play

------------------------------------------------------------------------

function load_bam_file(sequence filename)
  sequence bam
  printf(stdout,"opening \"%s\"\n",{filename})
  bam=get_whole_file(filename)
  if length(bam) then
    if length(bam)<4 or compare(bam[1..4],"CBMF") then
      --bam data is invalid, return false
      printf(stdout,"BAM data is invalid!\n",{})
      return(false)
    else
      return(bam[5..length(bam)])
    end if
  else  
    printf(stdout,"Cannot read file.\n",{})
    return(false)
  end if
end function

------------------------------------------------------------------------

procedure main ()
  integer key
  object bam
  integer pointer
  sequence label
  sequence loopcount
  integer chorusmarker
  integer bamcommand
  integer voice
  integer frequency
  integer labelnum
  integer jumpval
  integer delay
  atom nowtime
  integer vol

  bam=load_bam_file(bam_file_to_play)

  if sequence(bam) then
    
    pointer=1
    label=repeat(0,16) --labels set to zero are invalid
    label[1]=1 --the first label defaults to the beginning
    loopcount=repeat(0,16)
    chorusmarker=0 --if unset, the choursmarker is invalid

    --begin main loop
    while true do
    
      --read the keyboard
      key=get_key()
     
      --break the loop if any key is pressed
      if key>=0 then
        if key='-' then
          vol=large(get_fm_vol()-2,0)
          set_fm_vol(vol)
          printf(stdout,"volume down to %d\n",{vol})
        elsif key='+' then
          vol=small(get_fm_vol()+2,15)
          set_fm_vol(vol)
          printf(stdout,"volume up to %d\n",{vol})
        else  
          exit
        end if
      end if

      --break the loop if we reach the end of the data
      if pointer>length(bam) then
        exit
      end if

      bamcommand=bam[pointer]

      if bamcommand=0 then --stop song
        printf(stdout,"%04d: stop song\n",{pointer})
        exit
      elsif bamcommand>=16 and bamcommand<=31 then --start note
        voice=bamcommand-16
        pointer+=1
        frequency=bam[pointer]
        if frequency>127 then
          printf(stdout,"%04d: frequency %d is out of range\n",{pointer,frequency})
        end if
        printf(stdout,"%04d voice %d ON at %d\n",{pointer,voice,frequency})
        fm_voice_on(voice,frequency)
      elsif bamcommand>=32 and bamcommand<=47 then --stop note
        voice=bamcommand-32
        printf(stdout,"%04d voice %d OFF\n",{pointer,voice})
        fm_voice_off(voice)
      elsif bamcommand>=48 and bamcommand<=63 then --define instrument
        voice=bamcommand-48
        --read 11 data bytes to get the instrument
        printf(stdout,"%04d setting instrument for voice %d\n",{pointer,voice})
        set_fm_instrument(voice,bam[pointer+1..pointer+11])
        pointer+=11
      elsif bamcommand>=80 and bamcommand<=95 then --set label
        labelnum=bamcommand-80 +1
        printf(stdout,"%04d setting label %d\n",{pointer,labelnum})
        label[labelnum]=pointer
      elsif bamcommand>=96 and bamcommand<=111 then --jump
        labelnum=bamcommand-96 +1
        --read one byte to get the jump type
        pointer+=1
        jumpval=bam[pointer]
        --only jump when the label has been set
        if label[labelnum] then
          if jumpval=0 then --zero loop
            printf(stdout,"%04d ignoring zero-loop to label %d\n",{pointer,labelnum})
          elsif jumpval >=1 and jumpval<=253 then --finite loop
            if loopcount[labelnum]<jumpval then
              loopcount[labelnum]+=1
              printf(stdout,"%04d looping to label %d (%d of %d)\n",{pointer,labelnum,loopcount[labelnum],jumpval})
              pointer=label[labelnum]
            else
              printf(stdout,"%04d finished looping to label %d (%d loops)\n",{pointer,labelnum,jumpval})
              loopcount[labelnum]=0
            end if
          elsif jumpval=254 then --infinite loop
            printf(stdout,"%04d jumping to label %d\n",{pointer,labelnum})
            pointer=label[labelnum]
          elsif jumpval=255 then --chorus loop
            if chorusmarker>0 then
              printf(stdout,"%04d ignoring chorus %d, already in chorus mode\n",{pointer,labelnum})
            else  
              printf(stdout,"%04d jumping to chorus %d\n",{pointer,labelnum})
              chorusmarker=pointer
              pointer=label[labelnum]
            end if
          end if
        else
          printf(stdout,"%04d cannot jump to undefined label %d\n",{pointer,labelnum})
        end if
      elsif bamcommand=112 then --end-of-chorus
        if chorusmarker=0 then
          printf(stdout,"%04d ignoring end-of-chorus, not in chorus mode\n",{pointer})
        else
          pointer=chorusmarker
          chorusmarker=0
          printf(stdout,"%04d returning from chorus\n",{pointer})
        end if
      elsif bamcommand>=128 and bamcommand<=255 then --wait
        delay=bamcommand-127
        printf(stdout,"%04d wait %d\n",{pointer,delay})
        --approx .05 seconds per 1/32 note
        nowtime=time()
        --busy wait
        while nowtime+(delay/20)>time() do
        end while
      else
        printf(stdout,"%04d ignoring unknown BAM command %d\n",{pointer,bamcommand})
      end if
      
      --advance to the next command
      pointer+=1
        
    end while--end main loop

  end if--bam is good

end procedure

------------------------------------------------------------------------

procedure init ()
  tick_rate(120) --this improves the timer resolution, therefore improving
                 --sound quality, but has the downside of causing Windows
                 --to suspend the program when it is not in the foreground
  printf(stdout,"BAM player\n",{})
  if FM_SUPPORT=false then
    printf(stdout,"FM chip detect failed\n",{})
    abort(1)
  else
    printf(stdout,"FM chip detected\n",{})
  end if
  reset_fm()
  set_fm_melodic_mode()
  if length(command_line())<=2 then
    printf(stdout,"This program plays a BAM file, printing each command as it goes.\n",{})
    printf(stdout,"You must specify the filename on the command line.\n",{})
    abort(1)
  else
    bam_file_to_play=command_line()
    --only take the third argument
    bam_file_to_play=bam_file_to_play[3]
  end if
end procedure

------------------------------------------------------------------------

procedure cleanup()
  reset_fm()
end procedure

------------------------------------------------------------------------

init()
main()
cleanup()