include ports.e
include misc.e
include get.e

include bobsfile.e

------------------------------------------------------------------------

constant false=0
constant true=1

constant DEFAULT_FM_PORT=#0388

integer ADDR_PORT ADDR_PORT=DEFAULT_FM_PORT+#0
integer DATA_PORT DATA_PORT=DEFAULT_FM_PORT+#1

constant DEFAULT_MIXER_PORT=#0220

integer MIXER_ADDR_PORT MIXER_ADDR_PORT=DEFAULT_MIXER_PORT+#4
integer MIXER_DATA_PORT MIXER_DATA_PORT=DEFAULT_MIXER_PORT+#5
constant FM_VOL_REG=#26

constant FIRST_REG=#01
constant LAST_REG =#F5

constant LSI_REG       =#01
constant TIMER1_REG    =#02
constant TIMER_FLAG_REG=#04

constant INSTRUMENT_REG_TABLE={#20,#40,#60,#80,#E0}
constant FEEDBACK_REG        =#C0
constant VOICE_OPERATOR_OFFSET={#00,#01,#02,#08,#09,#0A,#10,#11,#12}

--build the operator table
sequence OPERATOR_TABLE
OPERATOR_TABLE={}
for i=1 to 9 do
  OPERATOR_TABLE=append(OPERATOR_TABLE,{})
  for j=1 to 5 do
    OPERATOR_TABLE[i] &= INSTRUMENT_REG_TABLE[j] + VOICE_OPERATOR_OFFSET[i]
    OPERATOR_TABLE[i] &= INSTRUMENT_REG_TABLE[j] + VOICE_OPERATOR_OFFSET[i] + 3
  end for
end for

constant FREQUENCY_REG      =#A0
constant KEY_REG            =#B0
constant MODE_REG           =#BD

global constant INST_DATA=1
global constant INST_NAME=2

constant NULL_INSTRUMENT={"",{#00,#00,#00,#00,#00,#00,#00,#00,#00,#00,#00}}
global constant DEFAULT_INSTRUMENT={"DEFAULT",{#21,#31,#4F,#80,#F2,#72,#52,#73,#00,#00,#06}}

constant NOTE_TABLE={0172,0182,0193,0205,0217,0230,0243,0258,0274,0290,0307
                    ,0326,0345,0365,0387,0410,0435,0460,0489,0517,0547,0580
                    ,0614,0651,1369,1389,1411,1434,1459,1484,1513,1541,1571
                    ,1604,1638,1675,2393,2413,2435,2458,2483,2508,2537,2565
                    ,2595,2628,2662,2699,3417,3437,3459,3482,3507,3532,3561
                    ,3589,3619,3652,3686,3723,4441,4461,4483,4506,4531,4556
                    ,4585,4613,4643,4676,4710,4747,5465,5485,5507,5530,5555
                    ,5580,5609,5637,5667,5700,5734,5771,6489,6509,6531,6554
                    ,6579,6604,6633,6661,6691,6724,6758,6795,7513,7533,7555
                    ,7578,7603,7628,7657,7685,7715,7748,7782,7819,7858,7898
                    ,7942,7988,8037,8089,8143,8191,8191,8191,8191,8191,8191
                    ,8191,8191,8191,8191,8191,8191,8191}


sequence LAST_FREQ LAST_FREQ={0,0,0,0,0,0,0,0,0}

global integer FM_SUPPORT

------------------------------------------------------------------------

function read_fm_status()
  byte result
  result=Input(ADDR_PORT)
  return result
end function

------------------------------------------------------------------------

procedure write_fm_register(byte reg,byte data)
  integer dummy

  --write the register number to the address port
  Output(reg,ADDR_PORT)
  
  --delay
  for i=1 to 6 do
    dummy=Input(ADDR_PORT)
  end for

  --write the data
  Output(data,DATA_PORT)

  --delay
  for i=1 to 35 do
    dummy=Input(ADDR_PORT)
  end for
  
end procedure

------------------------------------------------------------------------

function check_for_fm_support()
  integer result
  integer dummy
  byte status1,status2
  
  result=false

  --reset the timers  
  write_fm_register(TIMER_FLAG_REG,#60)
  
  --enable timer interrupts
  write_fm_register(TIMER_FLAG_REG,#80)

  --read the initial status  
  status1=read_fm_status()

  --start timer1
  write_fm_register(TIMER1_REG,#FF)
  write_fm_register(TIMER_FLAG_REG,#21)
  
  --delay for ~80ms
  for i=1 to 140 do
    dummy=Input(ADDR_PORT)
  end for

  --read status again
  status2=read_fm_status()

  --check the pre-and-post statuses
  if and_bits(status1,#E0)=#00 and and_bits(status2,#E0)=#C0 then
    result=true
  end if

  return result  
end function

------------------------------------------------------------------------

global procedure reset_fm()
  --clear all registers
  for i=FIRST_REG to LAST_REG do
    write_fm_register(i,0)
  end for
  --enable waveform by writing bit 5 in the LSI register
  write_fm_register(LSI_REG,#20)
end procedure

------------------------------------------------------------------------

global procedure set_fm_instrument(integer voice,sequence instrument)
  --voice is a number from 0 to 8
  --instrument is a string of 11 bytes in SBI format
  if voice >=0 and voice<=8 and length(instrument)>=11 then
    for i=1 to 10 do
      write_fm_register(OPERATOR_TABLE[voice+1][i],instrument[i])
    end for
    write_fm_register(FEEDBACK_REG+voice,instrument[11])
    --write_fm_register(FEEDBACK_REG+voice,#30)
  end if
end procedure

------------------------------------------------------------------------

global function read_ibk_instrument(sequence filename,integer index)
  integer fh
  sequence data
  sequence got_data
  sequence got_name

  got_data=DEFAULT_INSTRUMENT[INST_DATA]
  got_name=DEFAULT_INSTRUMENT[INST_NAME]
  
  if file_exists(filename) then
    fh=open(filename,"rb")
    data=get_bytes(fh,4)
    if compare(data,"IBK"&#1A) then
      --no IBK header
      return(NULL_INSTRUMENT)  
    end if
    for i=0 to 127 do
      data=get_bytes(fh,16)
      if i=index then
        got_data=data
      end if
    end for
    for i=0 to 127 do
      data=get_bytes(fh,9)
      if i=index then
        got_name=exclude(data,{0})
      end if
    end for
    close(fh)
    return({got_data,got_name})
  else
    --file does not exist
    return(NULL_INSTRUMENT)  
  end if
end function

------------------------------------------------------------------------

global procedure fm_voice_on(integer voice,integer freq)
  --voice is a number from 0 to 8
  --freq is a number from 0 to 127
  integer lowfreq,hifreq,octave
  if freq>=0 and freq<=127 then
    freq=NOTE_TABLE[freq+1]
    lowfreq=and_bits(freq,#FF)
    hifreq=and_bits(freq,#FF00)/#100
    octave=or_bits(hifreq,#20)
    if voice >=0 and voice<=8 then
      --turn the key on
      write_fm_register(FREQUENCY_REG+voice,lowfreq)
      write_fm_register(KEY_REG+voice,octave)
      --memorize the most signifigant bits for use in fm_voice_off
      LAST_FREQ[voice+1]=hifreq
    end if
  end if
end procedure

------------------------------------------------------------------------

global procedure fm_voice_off(integer voice)
  if voice >=0 and voice<=8 then
    write_fm_register(KEY_REG+voice,LAST_FREQ[voice+1])
  end if
end procedure

------------------------------------------------------------------------

global procedure set_fm_melodic_mode()
  write_fm_register(MODE_REG,#E0)
end procedure

------------------------------------------------------------------------

global procedure set_fm_vol(integer vol)
  vol=and_bits(vol,#F) --take the low nibble
  vol=or_bits(vol,vol*#10) --copy the low nibble to the high nibble
  Output(FM_VOL_REG,MIXER_ADDR_PORT)
  Output(vol,MIXER_DATA_PORT)
end procedure

------------------------------------------------------------------------

global function get_fm_vol()
  integer vol
  Output(FM_VOL_REG,MIXER_ADDR_PORT)
  vol=and_bits(Input(MIXER_DATA_PORT),#F)
  return(vol)
end function

------------------------------------------------------------------------

global procedure set_fm_base_port(integer port)
  ADDR_PORT=port+#0
  DATA_PORT=port+#1
  FM_SUPPORT=check_for_fm_support()
end procedure

------------------------------------------------------------------------

global procedure set_mixer_base_port(integer port)
  MIXER_ADDR_PORT=port+#4
  MIXER_DATA_PORT=port+#5
end procedure

------------------------------------------------------------------------

FM_SUPPORT=check_for_fm_support()