DEFINT A-Z
'$DYNAMIC
'$INCLUDE: 'fm.bi'

DECLARE SUB interpretBAM (fh%)

'QuickBasic must be started with the command
'line "QB /LFM" to load the FM.QLB library.
'see QB.BI for an explanation of each command

'This is a more advanced example that plays a BAM file manually without
'using loadsong(). This example will read from an open file, but it would
'also be possible to play data from an array buffer the same way

'because we will not be using loadsong(), we can make the music buffer
'very small.
DIM music%(0)

'now we initialize the soundcard
setupmusic music%()
resetfm

'init the volume fader to prevent unpredictable sudden loudness :)
fademusic getfmvol

'open the file for binary
filehandle = FREEFILE
'OPEN "..\sample\clfalse.bam" FOR BINARY AS #filehandle
OPEN "f:\midi2bam\nynym.bam" FOR BINARY AS #filehandle

'read the first four bytes to verify that this is a real BAM file
a$ = "xxxx"
GET #filehandle, 1, a$
IF a$ = "CBMF" THEN
  PRINT "BAM Header OK"
  PRINT "Playing `Clorinda False, Adeu'"
  interpretBAM filehandle
ELSE
  PRINT "BAM header not found"
END IF

'close the file
CLOSE #filehandle

'It is important to run closemusic at the any program that uses these
'routines. setupmusic replaces a timer interrupt, and closemusic restores
'it to its original state
closemusic

REM $STATIC
SUB interpretBAM (fh)

  'dim a 12 byte array to hold the 11 byte instrument
  DIM instrument(6)

  'space to store the 15 labels and their chorus/loop info
  DIM label(15), loopcount(15)
  chorusmarker = 0

  'the music starts at the fifth byte
  pointer = 5

  'label zero defaults to the beginning of the song (but can be overridden)
  label(0) = 4

  DO
   
    'break the loop if the user presses a key
    w$ = INKEY$
    IF w$ <> "" THEN EXIT DO

    'break the loop if the file ends
    IF EOF(fh) THEN EXIT DO

    'read one byte
    a$ = "x"
    GET #fh, pointer, a$
    bamcommand = ASC(a$)

    'do a different behavior depending on what command byte was read
    SELECT CASE bamcommand

    CASE 0 'stop-song
      PRINT pointer; "- End of Song"
      EXIT DO

    CASE 16 TO 31 'start-note
      voice = bamcommand - 16
     
      'read one data byte to get the frequency
      pointer = pointer + 1
      a$ = "x"
      GET #fh, pointer, a$
      frequency = ASC(a$)
     
      IF frequency > 127 THEN PRINT pointer; "- frequency"; frequency; "is out of range"
      PRINT pointer; "- Voice"; voice; "ON at"; frequency

      FMKeyOn voice, frequency
   
    CASE 32 TO 47 'stop-note
      voice = bamcommand - 32
      PRINT pointer; "- Voice"; voice; "OFF"

      FMKeyOff voice

    CASE 48 TO 63 'define-instrument
      voice = bamcommand - 48

      'read 11 data bytes to get the instrument
      pointer = pointer + 1
      'read 12 bytes
      FOR i = 0 TO 5
        GET #fh, pointer + (2 * i), instrument(i)
      NEXT i
      'get rid of the last byte
      instrument(6) = (instrument(6) AND 255)
      pointer = pointer + 10

      PRINT pointer; "- Defining voice"; voice

      setvoice voice, instrument()

    CASE 80 TO 95 'set-label
      labelnum = bamcommand - 80

      PRINT pointer; "- Set label"; labelnum

      label(labelnum) = pointer

    CASE 96 TO 111 'jump
      labelnum = bamcommand - 96

      'read one data byte to get the jump type
      pointer = pointer + 1
      a$ = "x"
      GET #fh, pointer, a$
      jumpval = ASC(a$)

      'only jump if the label has been set
      IF label(labelnum) > 0 THEN

        SELECT CASE jumpval

        CASE 0
          PRINT pointer; "- ignoring zero-loop to label"; labelnum

        CASE 1 TO 253 ' finite loop
          IF loopcount(labelnum) < jumpval THEN
            loopcount(labelnum) = loopcount(labelnum) + 1
            PRINT pointer; "- Looping to label"; labelnum; "("; loopcount(labelnum); "of"; jumpval; ")"
            pointer = label(labelnum)
          ELSE
            PRINT pointer; "- Finished looping to label"; labelnum; "("; jumpval; " loops )"
            loopcount(labelnum) = 0
          END IF
       
        CASE 254 ' infinite loop
          PRINT pointer; "- Jumping to label"; labelnum
          pointer = label(labelnum)

        CASE 255 ' chorus loop
          IF chorusmarker > 0 THEN
            PRINT pointer; "- Ignoring chorus"; labelnum; "Already in chorus mode"
          ELSE
            PRINT pointer; "- Jumping to chorus"; labelnum
            chorusmarker = pointer
            pointer = label(labelnum)
          END IF

        END SELECT

      ELSE
        PRINT pointer; "- Cannot jump to undefined label"; labelnum
      END IF

    CASE 112 'end-of-chorus
      IF chorusmarker = 0 THEN
        PRINT pointer; "- Ingnoring end-of-chorus, not in chorus mode"
      ELSE
        pointer = chorusmarker
        chorusmarker = 0
        PRINT pointer; "- Returning from chorus"
      END IF

    CASE 128 TO 255 'wait
      delay = bamcommand - 127

      PRINT pointer; "- Wait"; delay

      'estimating about .05 of a second per 1/32 note
      t! = TIMER
      WHILE t! + (delay / 20) > TIMER: WEND

    CASE ELSE 'reserved
      PRINT pointer; "- Ignoring unknown BAM command"; bamcommand

    END SELECT

    'move to the next command
    pointer = pointer + 1

  LOOP

  'just in case any voices where still playing
  FOR voice = 0 TO 8
    FMKeyOff voice
  NEXT voice

END SUB