;*****************************************************************************

;*** Redraw a screen from a map and page of map blocks
;* This should work okay...
;* Brian Fisher
;*
;*

.386
Ideal
Model Small
Public setmapdata,setmapblock,readmapblock,drawmap
CodeSeg

mapx    dw ?
mapy    dw ?
topbar  dw 0
botbar  dw 200
mapoff  dw ?
mapseg  dw ?
write	db ?
read 	db 0
howmany	dw ?
lines	dw ?
extra 	dw 0
maploc	dw ?
blocks  dw 0
screen	dw 0
gap	dw 0

Proc    Setmapdata      ; array, top bar, bottom
	push bp
	mov bp,sp
	push ds si

	mov bx,[ss:bp+10]
	mov si,[ds:bx+0ah]
	mov ds,[ds:bx+02h]
	lodsw
	mov [mapx],ax
	lodsw
	mov [mapy],ax
	mov [mapseg],ds
	mov [mapoff],si
	mov ax,[ss:bp+08]
	mov [topbar],ax		;topbar= lines to move down
	mov bx,200
	sub bx,ax
	mov ax,[ss:bp+06]
	sub bx,ax
	mov [botbar],bx         ;Botbar= lines to draw
	pop si ds bp
	retf 6
endp    Setmapdata

Proc    SetMapBlock     ; X, Y, Value
	push bp
	mov bp,sp
	push es di
	
	mov ax,[mapseg]
	mov es,ax
	mov di,[mapoff]
	mov ax,[ss:bp+08]
	mov bx,[mapx]
	mul bx
	mov bx,[ss:bp+10]
	add ax,bx
	add di,ax
	mov ax,[ss:bp+06]
	stosb

	pop di es bp
	retf 6
endp    SetMapBlock

Proc    ReadMapBlock    ; X, Y
	push bp
	mov bp,sp
	push ds si

	mov ax,[mapseg]
	mov ds,ax
	mov si,[mapoff]
	mov ax,[mapx]
	mov bx,[ss:bp+06]
	mul bx
	mov bx,[ss:bp+08]
	add ax,bx
	add si,ax
	lodsb
	xor ah,ah

	pop si ds bp
	retf 4
endp    ReadMapBlock
	
Proc    Drawmap        ; X, Y, Page
	push bp
	mov bp,sp
	push es di ds si

	mov ax,0a000h
	mov es,ax
	mov ax,[ss:bp+06]	;get dest. offset
	shl ax,14
	mov [screen],ax		;set screen to offset for screen
	mov ax,80
	mul [topbar]
	add [screen],ax		;move down for top status bar
	mov ax,[ss:bp+08]
	add ax,[topbar]
	mov bx,20
	div bl
	sub bl,ah
	mov [howmany],bx	;set howmany for top row
	mov cl,ah
	xor ch,ch
	mov bx,cx
	shl bx,4
	shl cx,6
	add cx,bx
	mov [extra],cx		;set pixel adjustment to read blocks for first row
	xor ah,ah
	mul [mapx]
	mov bx,ax
	xor dx,dx
	mov ax,[ss:bp+10]
	mov cx,20
	div cx
	sub cx,dx
	mov [gap],0
	cmp cx,20
	jz nosides
	mov [gap],cx
	shr cx,2
	add [screen],cx
	add bx,1
nosides:
	add bx,ax
	add bx,[mapoff]
	mov [maploc],bx		;set map block number
	mov ax,[botbar]
	mov [lines],ax
loop4:		;set up a column
	mov cx,[gap]
	mov ax,1
	and cx,3
	shl al,cl
	mov [write],al		;set write to x value
	mov [blocks],15
	push [maploc]
loop3:		;set up a new block
	mov di,[screen]
	mov [read],0		;set read to take first column
	mov ds,[mapseg]
	mov si,[maploc]
	mov al,[ds:si]		;read map blocknumber to draw
	xor ah,ah
	mov bx,es
	mov ds,bx
	mov si,49152
	mov cx,ax
	and ax,15
	mov bx,5
	mul bx
	add si,ax		;add blocknumber mod 16 times 5 to the reading screen
	shr cx,4
	mov ax,1600
	mul cx
	add si,ax		;add blocknumber div 16 times 1600
	add si,[extra]		;add for starting row
loop2:		;draw a block
	mov al,02h
	mov ah,[write]
	mov dx,03c4h
	out dx,ax       	;set the write plane enable
	mov dx,3ceh
	mov al,04h
	mov ah,[read]
	out dx,ax		;set the read plane enable
	mov cx,[howmany]
loop1:		;draw a fourth of a block
	movsd
	movsb
	add si,75
	add di,75
	loop loop1
	mov ax,80
	mul [howmany]
	sub si,ax
	sub di,ax
	mov al,[write]
	mov bl,[write]
	shr al,3
	xor ah,ah
	add di,ax
	shl bl,1
	and bx,0fh
	add ax,bx
	mov [write],al
	inc [read]
	cmp [read],4
	jb loop2		;do another set o' columns
	add [screen],5
	inc [maploc]
	dec [blocks]
	cmp [blocks],0
	ja loop3		;do another block
	pop [maploc]
	sub [screen],75
	mov ax,80
	mul [howmany]
	add [screen],ax
	mov ax,[mapx]
	add [maploc],ax
	mov [extra],0
	mov ax,[howmany]
	sub [lines],ax
	jna donewithcenter
	mov [howmany],20
	cmp [lines],20
	ja loop4
	mov ax,[lines]
	mov [howmany],ax
	jmp loop4		;do another row
donewithcenter:
	pop si ds di es bp
	retf 6
endp    Drawmap
end